{{{#!table align=right
||04/01/21||
}}}
= Lab <028> - 한/영타 변환기 =

글을 입력하면 자동으로 변환된다.
{{{#!html
<input type="text" id="txtSource" size=50><br>
<input type="radio" id="optEtoH" name="Mode" checked><label for="optEtoH">영타 → 한글</label> 
<input type="radio" id="optHtoE" name="Mode"><label for="optHtoE">한타 → 영어</label><br>
<input type="text" id="txtConv" size=50>

<script language="VBScript">
<!--
Const EngDat = "rRseEfaqQtTdwWczxvgkoiOjpuPhynbml"
Const HanDat = "ㄱㄲㄴㄷㄸㄹㅁㅂㅃㅅㅆㅇㅈㅉㅊㅋㅌㅍㅎㅏㅐㅑㅒㅓㅔㅕㅖㅗㅛㅜㅠㅡㅣ"
Const ChoDat = "ㄱㄲㄴㄷㄸㄹㅁㅂㅃㅅㅆㅇㅈㅉㅊㅋㅌㅍㅎ"
Const JungDat = "ㅏㅐㅑㅒㅓㅔㅕㅖㅗㅘㅙㅚㅛㅜㅝㅞㅟㅠㅡㅢㅣ"
Const JongDat = "ㄱㄲㄳㄴㄵㄶㄷㄹㄺㄻㄼㄽㄾㄿㅀㅁㅂㅄㅅㅆㅇㅈㅊㅋㅌㅍㅎ"

Private Sub optEtoH_OnClick()
txtSource_OnKeyUp
End Sub

Private Sub optHtoE_OnClick()
txtSource_OnKeyUp
End Sub

Private Sub txtSource_OnKeyUp()
If optEtoH.Checked Then
	txtConv.Value = EngTypeToHan(txtSource.Value)
Else
	txtConv.Value = HanTypeToEng(txtSource.Value)
End If
End Sub

Function EngTypeToHan(Source)
Dim ConvText, tChr
Dim Cho, Jung, Jong, tVal    '초성, 중성, 종성, (임시용) 초성
Dim i, p

If Len(Source) = 0 Then Exit Function
For i = 1 To Len(Source)
	tChr = Mid(Source, i, 1)
	p = InStr(EngDat, tChr)
	If p = 0 Then               '영자판이 아님
		If Cho Then
			If Jung Then       '초성+중성+(종성)
				ConvText = ConvText + MakeHan(Cho - 1, Jung - 1, Jong)
			Else                '초성만
				ConvText = ConvText + Mid(ChoDat, Cho, 1)
			End If
		Else
			If Jung Then       '중성만
				ConvText = ConvText + Mid(JungDat, Jung, 1)
			Else                '복자음
				If Jong Then ConvText = ConvText + Mid(JongDat, Jong, 1)
			End If
		End If
		Cho = 0: Jung = 0: Jong = 0
		ConvText = ConvText + tChr
	ElseIf p < 20 Then          '자음
		If Jung Then
			If Cho = 0 Then            '중성만 입력됨, 초성으로
				ConvText = ConvText + Mid(JungDat, Jung, 1)
				Jung = 0
				Cho = InStr(ChoDat, Mid(HanDat, p, 1))
			Else                        '종성이다
				If Jong = 0 Then       '종성 입력 중
					Jong = InStr(JongDat, Mid(HanDat, p, 1))
					If Jong = 0 Then           '종성이 아니라 초성이다
						ConvText = ConvText + MakeHan(Cho - 1, Jung - 1, Jong)
						Cho = InStr(ChoDat, Mid(HanDat, p, 1)): Jung = 0
					End If
				ElseIf Jong = 1 And p = 10 Then        'ㄳ
					Jong = 3
				ElseIf Jong = 4 And p = 13 Then        'ㄵ
					Jong = 5
				ElseIf Jong = 4 And p = 19 Then        'ㄶ
					Jong = 6
				ElseIf Jong = 8 And p = 1 Then         'ㄺ
					Jong = 9
				ElseIf Jong = 8 And p = 7 Then         'ㄻ
					Jong = 10
				ElseIf Jong = 8 And p = 8 Then         'ㄼ
					Jong = 11
				ElseIf Jong = 8 And p = 10 Then        'ㄽ
					Jong = 12
				ElseIf Jong = 8 And p = 17 Then        'ㄾ
					Jong = 13
				ElseIf Jong = 8 And p = 18 Then        'ㄿ
					Jong = 14
				ElseIf Jong = 8 And p = 19 Then        'ㅀ
					Jong = 15
				ElseIf Jong = 17 And p = 10 Then       'ㅄ
					Jong = 18
				Else                    '종성 입력 끝, 초성으로
					ConvText = ConvText + MakeHan(Cho - 1, Jung - 1, Jong)
					Cho = InStr(ChoDat, Mid(HanDat, p, 1))
					Jung = 0: Jong = 0
				End If
			End If
		Else                '초성 또는 (단/복)자음이다
			If Cho = 0 Then            '초성 입력 시작
				If Jong Then           '복자음 후 초성
					ConvText = ConvText + Mid(JongDat, Jong, 1)
					Jong = 0
				End If
				Cho = InStr(ChoDat, Mid(HanDat, p, 1))
			ElseIf Cho = 1 And p = 10 Then         'ㄳ
				Cho = 0: Jong = 3
			ElseIf Cho = 3 And p = 13 Then         'ㄵ
				Cho = 0: Jong = 5
			ElseIf Cho = 3 And p = 19 Then         'ㄶ
				Cho = 0: Jong = 6
			ElseIf Cho = 6 And p = 1 Then          'ㄺ
				Cho = 0: Jong = 9
			ElseIf Cho = 6 And p = 7 Then          'ㄻ
				Cho = 0: Jong = 10
			ElseIf Cho = 6 And p = 8 Then          'ㄼ
				Cho = 0: Jong = 11
			ElseIf Cho = 6 And p = 10 Then         'ㄽ
				Cho = 0: Jong = 12
			ElseIf Cho = 6 And p = 17 Then         'ㄾ
				Cho = 0: Jong = 13
			ElseIf Cho = 6 And p = 18 Then         'ㄿ
				Cho = 0: Jong = 14
			ElseIf Cho = 6 And p = 19 Then         'ㅀ
				Cho = 0: Jong = 15
			ElseIf Cho = 8 And p = 10 Then         'ㅄ
				Cho = 0: Jong = 18
			Else                                    '단자음을 연타
				ConvText = ConvText + Mid(ChoDat, Cho, 1)
				Cho = InStr(ChoDat, Mid(HanDat, p, 1))
			End If
		End If
	Else                    '중성
		If Jong Then       '(앞글자 종성), 초성+중성
			Select Case Jong       '복자음 다시 분해
				Case 3: Jong = 1: tVal = 10            'ㄱ, ㅅ
				Case 5: Jong = 4: tVal = 13            'ㄴ, ㅈ
				Case 6: Jong = 4: tVal = 19            'ㄴ, ㅎ
				Case 9: Jong = 8: tVal = 1             'ㄹ, ㄱ
				Case 10: Jong = 8: tVal = 7            'ㄹ, ㅁ
				Case 11: Jong = 8: tVal = 8            'ㄹ, ㅂ
				Case 12: Jong = 8: tVal = 10           'ㄹ, ㅅ
				Case 13: Jong = 8: tVal = 17           'ㄹ, ㅌ
				Case 14: Jong = 8: tVal = 18           'ㄹ, ㅍ
				Case 15: Jong = 8: tVal = 19           'ㄹ, ㅎ
				Case 18: Jong = 17: tVal = 10          'ㅂ, ㅅ
				Case Else           '복자음 아님
					tVal = InStr(ChoDat, Mid(JongDat, Jong, 1))
					Jong = 0
			End Select
			If Cho Then            '앞글자가 초성+중성+(종성)
				ConvText = ConvText + MakeHan(Cho - 1, Jung - 1, Jong)
			Else                    '복자음만 있음
				ConvText = ConvText + Mid(JongDat, Jong, 1)
			End If
			Cho = tVal: Jung = 0: Jong = 0
		End If
		If Jung = 0 Then                           '중성 입력 중
			Jung = InStr(JungDat, Mid(HanDat, p, 1))
		ElseIf Jung = 9 And p = 20 Then            'ㅘ
			Jung = 10
		ElseIf Jung = 9 And p = 21 Then            'ㅙ
			Jung = 11
		ElseIf Jung = 9 And p = 33 Then            'ㅚ
			Jung = 12
		ElseIf Jung = 14 And p = 24 Then           'ㅝ
			Jung = 15
		ElseIf Jung = 14 And p = 25 Then           'ㅞ
			Jung = 16
		ElseIf Jung = 14 And p = 33 Then           'ㅟ
			Jung = 17
		ElseIf Jung = 19 And p = 33 Then           'ㅢ
			Jung = 20
		Else                '조합 안되는 모음 입력
			If Cho Then        '초성+중성 후 중성
				ConvText = ConvText + MakeHan(Cho - 1, Jung - 1, Jong)
				Cho = 0
			Else                '중성 후 중성
				ConvText = ConvText + Mid(JungDat, Jung, 1)
			End If
			Jung = 0
			ConvText = ConvText + Mid(HanDat, p, 1)
		End If
	End If
Next
If Cho Then             '마지막 한글이 있으면 처리
	If Jung Then        '초성+중성+(종성)
		ConvText = ConvText + MakeHan(Cho - 1, Jung - 1, Jong)
	Else                '초성만
		ConvText = ConvText + Mid(ChoDat, Cho, 1)
	End If
Else
	If Jung Then        '중성만
		ConvText = ConvText + Mid(JungDat, Jung, 1)
	Else                '복자음
		If Jong Then ConvText = ConvText + Mid(JongDat, Jong, 1)
	End If
End If

EngTypeToHan = ConvText
End Function

Function MakeHan(nChoSung, nJungSung, nJongSung)
MakeHan = ChrW(&HAC00 + nChoSung * 21 * 28 + nJungSung * 28 + nJongSung)
End Function

Function HanTypeToEng(Source)
Dim ConvText, tChr, tAsc
Dim Jung, Cho, Jong, tVal(5)
Dim i

If Len(Source) = 0 Then Exit Function
For i = 1 To Len(Source)
	tChr = Mid(Source, i, 1)
	tAsc = AscW(tChr)
	Cho = InStr(ChoDat, tChr)
	Jung = InStr(JungDat, tChr)
	Jong = InStr(JongDat, tChr)
	
	If &HAC00 <= tAsc And tAsc <= &HD7A3 Then
		tAsc = tAsc - &HAC00
		tVal(1) = 1 + tAsc \ (21 * 28)              '초성
		tVal(2) = 1 + (tAsc \ 28) Mod 21            '중성
		tVal(4) = tAsc Mod 28                       '종성
	ElseIf Cho Then             '초성 자음
		tVal(1) = Cho: tVal(2) = 0: tVal(4) = 0
	ElseIf Jung Then            '중성
		tVal(1) = 0: tVal(2) = Jung: tVal(4) = 0
	ElseIf Jong Then            '종성 자음
		tVal(1) = 0: tVal(2) = 0: tVal(4) = Jong
	Else                        '한글이 아님
		ConvText = ConvText + tChr
		tVal(1) = 0: tVal(2) = 0: tVal(4) = 0
	End If
	
	If tVal(1) Then ConvText = ConvText + Mid(EngDat, tVal(1), 1)
	If tVal(2) Then
		Select Case tVal(2)
			Case 10: tVal(2) = 9: tVal(3) = 1       'ㅘ
			Case 11: tVal(2) = 9: tVal(3) = 2       'ㅙ
			Case 12: tVal(2) = 9: tVal(3) = 14      'ㅚ
			Case 15: tVal(2) = 11: tVal(3) = 5      'ㅝ
			Case 16: tVal(2) = 11: tVal(3) = 6      'ㅞ
			Case 17: tVal(2) = 11: tVal(3) = 14     'ㅟ
			Case 20: tVal(2) = 13: tVal(3) = 14     'ㅢ
			Case Else
				tVal(2) = InStr(HanDat, Mid(JungDat, tVal(2), 1)) - 19
				tVal(3) = 0
		End Select
		ConvText = ConvText + Mid(EngDat, tVal(2) + 19, 1)
		If tVal(3) Then ConvText = ConvText + Mid(EngDat, tVal(3) + 19, 1)
	End If
	If tVal(4) Then
		Select Case tVal(4)
			Case 3: tVal(4) = 1: tVal(5) = 10       'ㄳ
			Case 5: tVal(4) = 3: tVal(5) = 13       'ㄵ
			Case 6: tVal(4) = 3: tVal(5) = 19       'ㄶ
			Case 9: tVal(4) = 6: tVal(5) = 1        'ㄺ
			Case 10: tVal(4) = 6: tVal(5) = 7       'ㄻ
			Case 11: tVal(4) = 6: tVal(5) = 8       'ㄼ
			Case 12: tVal(4) = 6: tVal(5) = 10      'ㄽ
			Case 13: tVal(4) = 6: tVal(5) = 17      'ㄾ
			Case 14: tVal(4) = 6: tVal(5) = 18      'ㄿ
			Case 15: tVal(4) = 6: tVal(5) = 19      'ㅀ
			Case 18: tVal(4) = 8: tVal(5) = 10      'ㅄ
			Case Else
				tVal(4) = InStr(HanDat, Mid(JongDat, tVal(4), 1))
				tVal(5) = 0
		End Select
		ConvText = ConvText + Mid(EngDat, tVal(4), 1)
		If tVal(5) Then ConvText = ConvText + Mid(EngDat, tVal(5), 1)
	End If
Next

HanTypeToEng = ConvText
End Function
-->
</script>
}}}
----
[wiki:Lab분류]